22b6e15a17
e5f9940 Merge commit '1bc3dd200b023cecf063a0cb3ba347f77f6d759d' into core_update da03c50 Add note for L/R side bit being ignored e80f3c1 Add in basic documentation for Macro system 35e8a76 core: Swap position of PEQL and PENT in unimap 00751f1 Merge pull request #406 from 39aldo39/patch-1 e50d7de V-USB remote wakeup 4340997 core: Fix typo in definition AC_g 958144d core: Debug print for system and consumer keys e7e1030 core: Fix sleep_led 0866323 core: Change matrix_init and matrix_print 0dbf73d core: Add matrix_clear() and default impl. 3202ca3 core: Add suspend mode options 4cda3aa core: Fix suspend/wake for converters #386 4e15247 core: LUFA_DEBUG_SUART for serial debug b9cf8e7 core: Fix mechanical locking supoort #390 12aa0fd Merge branch 'nemith-master' fccb3fa core: Fix OPT_DEFS for mbed build 2e2d2c8 Merge branch 'master' of github.com:leizzer/tmk_keyboard f1d3634 Change .gitignore for ChibiOS 3aab802 core: Fix build config in protocol.mk 5e43da0 core: Add short names in unimap 7a56998 core: Fix dfu wait in rules.mk 6d9c500 Merge branch 'mediakey-fix' 08382ac core: Fix 'make dfu' message 78cb04e Fix OS X Recognizing keyboard as Mouse/Tablet a114714 core: 'make dfu' waits for bootloader to start d0a8f13 core: Fix unimap UNIMAP_NO case e17abef core: Change lufa NKRO report size 16 to 32 bytes 375b20f core: Fix common.mk for build options 394fdff core: Fix unimap layout comment 912326c core: Add unimap support 00f4011 core: Fix doc/keymap.md for new keymap framework ddbd7b4 core: Add default implemenation of keymap read 671cacc core: action codes are action_t struct now b4fdb27 core: Change chibios repo directory names 7daed10 core: Fix keycode.txt 90399d7 core: Fix USB remote wakeup on ATmega32U2 #361 3677e84 usb_usb: Add multiple keyboard support 54d5b26 core: Fix Logical Maximum in report descriptor bd0d372 core: Fix LUFA report descriptor 95327b5 Merge pull request #355 from papodaca/XT 62bf548 core: change API of adb.c to accept device address 3097c9e Fix function name in host.h 836e209 Merge branch 'core_split_160522' 3918ea2 Merge commit '20b787fc1284176834cbe7ca2134e4b36bec5828' 7f87b11 core: Add comment of register 3 of ADB ef6478a core: Add adb_host_talk() 5c665b4 update macro names in bluefruit 4f2c5bf Merge commit '71381457fa1311dfa0b58ba882a96db740640871' 53a9c08 Merge pull request #321 from njbair/master f08a656 core: Fix media/consumer keys d526de8 Clean up wording in keymap example 0bb3dbb Clarify layer precedence d915c75 clarify layer documentation 72070d4 ps2_usb: Fix for VUSB configuration 170e2dc Mostly working. Is unstable, will emit bad codes after a while. c8e45b5 core: Actionmap support aabaa24 Codes appear to be detected correctly, the break codes are broken. git-subtree-dir: tmk_core git-subtree-split: e5f994033cbc8700745ac0c6d12772820492eed0
156 lines
3.9 KiB
ArmAsm
156 lines
3.9 KiB
ArmAsm
;---------------------------------------------------------------------------;
|
|
; Software implemented UART module ;
|
|
; (C)ChaN, 2005 (http://elm-chan.org/) ;
|
|
;---------------------------------------------------------------------------;
|
|
; Bit rate settings:
|
|
;
|
|
; 1MHz 2MHz 4MHz 6MHz 8MHz 10MHz 12MHz 16MHz 20MHz
|
|
; 2.4kbps 138 - - - - - - - -
|
|
; 4.8kbps 68 138 - - - - - - -
|
|
; 9.6kbps 33 68 138 208 - - - - -
|
|
; 19.2kbps - 33 68 102 138 173 208 - -
|
|
; 38.4kbps - - 33 50 68 85 102 138 172
|
|
; 57.6kbps - - 21 33 44 56 68 91 114
|
|
; 115.2kbps - - - - 21 27 33 44 56
|
|
|
|
.nolist
|
|
#include <avr/io.h>
|
|
.list
|
|
|
|
#define BPS 44 /* Bit delay. (see above table) */
|
|
#define BIDIR 0 /* 0:Separated Tx/Rx, 1:Shared Tx/Rx */
|
|
|
|
#define OUT_1 sbi _SFR_IO_ADDR(SUART_OUT_PORT), SUART_OUT_BIT /* Output 1 */
|
|
#define OUT_0 cbi _SFR_IO_ADDR(SUART_OUT_PORT), SUART_OUT_BIT /* Output 0 */
|
|
#define SKIP_IN_1 sbis _SFR_IO_ADDR(SUART_IN_PIN), SUART_IN_BIT /* Skip if 1 */
|
|
#define SKIP_IN_0 sbic _SFR_IO_ADDR(SUART_IN_PIN), SUART_IN_BIT /* Skip if 0 */
|
|
|
|
|
|
|
|
#ifdef SPM_PAGESIZE
|
|
.macro _LPMI reg
|
|
lpm \reg, Z+
|
|
.endm
|
|
.macro _MOVW dh,dl, sh,sl
|
|
movw \dl, \sl
|
|
.endm
|
|
#else
|
|
.macro _LPMI reg
|
|
lpm
|
|
mov \reg, r0
|
|
adiw ZL, 1
|
|
.endm
|
|
.macro _MOVW dh,dl, sh,sl
|
|
mov \dl, \sl
|
|
mov \dh, \sh
|
|
.endm
|
|
#endif
|
|
|
|
|
|
|
|
;---------------------------------------------------------------------------;
|
|
; Transmit a byte in serial format of N81
|
|
;
|
|
;Prototype: void xmit (uint8_t data);
|
|
;Size: 16 words
|
|
|
|
.global xmit
|
|
.func xmit
|
|
xmit:
|
|
#if BIDIR
|
|
ldi r23, BPS-1 ;Pre-idle time for bidirectional data line
|
|
5: dec r23 ;
|
|
brne 5b ;/
|
|
#endif
|
|
in r0, _SFR_IO_ADDR(SREG) ;Save flags
|
|
|
|
com r24 ;C = start bit
|
|
ldi r25, 10 ;Bit counter
|
|
cli ;Start critical section
|
|
|
|
1: ldi r23, BPS-1 ;----- Bit transferring loop
|
|
2: dec r23 ;Wait for a bit time
|
|
brne 2b ;/
|
|
brcs 3f ;MISO = bit to be sent
|
|
OUT_1 ;
|
|
3: brcc 4f ;
|
|
OUT_0 ;/
|
|
4: lsr r24 ;Get next bit into C
|
|
dec r25 ;All bits sent?
|
|
brne 1b ; no, coutinue
|
|
|
|
out _SFR_IO_ADDR(SREG), r0 ;End of critical section
|
|
ret
|
|
.endfunc
|
|
|
|
|
|
|
|
;---------------------------------------------------------------------------;
|
|
; Receive a byte
|
|
;
|
|
;Prototype: uint8_t rcvr (void);
|
|
;Size: 19 words
|
|
|
|
.global rcvr
|
|
.func rcvr
|
|
rcvr:
|
|
in r0, _SFR_IO_ADDR(SREG) ;Save flags
|
|
|
|
ldi r24, 0x80 ;Receiving shift reg
|
|
cli ;Start critical section
|
|
|
|
1: SKIP_IN_1 ;Wait for idle
|
|
rjmp 1b
|
|
2: SKIP_IN_0 ;Wait for start bit
|
|
rjmp 2b
|
|
ldi r25, BPS/2 ;Wait for half bit time
|
|
3: dec r25
|
|
brne 3b
|
|
|
|
4: ldi r25, BPS ;----- Bit receiving loop
|
|
5: dec r25 ;Wait for a bit time
|
|
brne 5b ;/
|
|
lsr r24 ;Next bit
|
|
SKIP_IN_0 ;Get a data bit into r24.7
|
|
ori r24, 0x80
|
|
brcc 4b ;All bits received? no, continue
|
|
|
|
out _SFR_IO_ADDR(SREG), r0 ;End of critical section
|
|
ret
|
|
.endfunc
|
|
|
|
|
|
; Not wait for start bit. This should be called after detecting start bit.
|
|
.global recv
|
|
.func recv
|
|
recv:
|
|
in r0, _SFR_IO_ADDR(SREG) ;Save flags
|
|
|
|
ldi r24, 0x80 ;Receiving shift reg
|
|
cli ;Start critical section
|
|
|
|
;1: SKIP_IN_1 ;Wait for idle
|
|
; rjmp 1b
|
|
;2: SKIP_IN_0 ;Wait for start bit
|
|
; rjmp 2b
|
|
ldi r25, BPS/2 ;Wait for half bit time
|
|
3: dec r25
|
|
brne 3b
|
|
|
|
4: ldi r25, BPS ;----- Bit receiving loop
|
|
5: dec r25 ;Wait for a bit time
|
|
brne 5b ;/
|
|
lsr r24 ;Next bit
|
|
SKIP_IN_0 ;Get a data bit into r24.7
|
|
ori r24, 0x80
|
|
brcc 4b ;All bits received? no, continue
|
|
|
|
ldi r25, BPS/2 ;Wait for half bit time
|
|
6: dec r25
|
|
brne 6b
|
|
7: SKIP_IN_1 ;Wait for stop bit
|
|
rjmp 7b
|
|
|
|
out _SFR_IO_ADDR(SREG), r0 ;End of critical section
|
|
ret
|
|
.endfunc
|